﻿// Copyright 2007. Adobe Systems Incorporated. All Rights Reserved.
package com.adobe.captivate.events 
{
	import flash.events.Event;
	import com.adobe.captivate.widgets.CPSlideProperties;

	/**
	 * The CPSlideExitEvent class describes the event object passed to the event listener when a slide finishes playing
	 */
	public class CPSlideExitEvent extends CaptivateEvent 
	{
		/**
		*  The <code>CPSlideExitEvent.CPSLIDEEXITEVENT</code> constant defines the value of the
		*  <code>type</code> property of the event object for an <code>CPSlideExitEvent</code> event.
		*  <p>The properties of the event object have the following values:</p>
		*  <table class="innertable">
		*     <tr><th>Property</th><th>Value</th></tr>
		*     <tr><td><code>bubbles</code></td><td><code>true</code></td></tr>
		*     <tr><td><code>frameNumber</code></td><td>The frame number at which the slide has finished playing</td></tr>
		*     <tr><td><code>slideNumber</code></td><td>The index of the slide that has finished playing( index is 1 based)</td></tr>
		*     <tr><td><code>slideLabel</code></td><td>The slide label of the slide that has finished playing</td></tr>
		*     <tr><td><code>slideProperties</code></td><td>The slide properties of the slide that has finished playing</td></tr>
		*     <tr><td><code>cancelable</code></td><td><code>false</code></td></tr>
		*	</table>
		* @eventType CPSlideExitEvent 	
		*/
		public static const CPSLIDEEXITEVENT:String = "CPSlideExitEvent";
		/**
		* @private
		*/
		protected var m_FrameNumber:Number;
		/**
		* @private
		*/
		protected var m_SlideNumber:Number;
		/**
		* @private
		*/
		protected var m_SlideLabel:String;
		/**
		* @private
		*/
		protected var m_SlideProperties:CPSlideProperties;
		/**
		* @private
		*/
		protected var m_PercentageSlidesSeen:Number;
		/**
		* @private
		*/
		public function CPSlideExitEvent(captivateVersion:String="",frameNumber:Number=0,slideNumber:Number=0,
			slideLabel:String="",slideProperties:CPSlideProperties=null,cancelable:Boolean = false,percentageSlidesSeen:Number=0) 
		{
			super(CPSlideExitEvent.CPSLIDEEXITEVENT,captivateVersion,cancelable);
			m_FrameNumber = frameNumber;
			m_SlideNumber = slideNumber;
			m_SlideLabel = slideLabel;
			m_SlideProperties = slideProperties;
			m_PercentageSlidesSeen = percentageSlidesSeen;
		}
		/**
		* @private
		*/
		public override function clone():Event
		{
			return new CPSlideExitEvent(captivateVersion,frameNumber,slideNumber,slideLabel,slideProperties,cancelable);
		}
		
		/** 
		* The frame number at which the slide has finished playing
		*/
		public function get frameNumber():Number
		{
			return m_FrameNumber;
		}
		
		/** 
		* The index of the slide that has finished playing( index is 1 based)
		*/
		public function get slideNumber():Number
		{
			return m_SlideNumber;
		}
		
		/** 
		* The slide label of the slide that has finished playing
		*/
		public function get slideLabel():String
		{
			return m_SlideLabel;
		}
		
		/** 
		* The slide properties of the slide that has finished playing
		* @see com.adobe.captivate.widgets.CPSlideProperties
		*/
		public function get slideProperties():CPSlideProperties
		{
			return m_SlideProperties;
		}
		/** 
		* The percentage of slides seen by the learner so far. Possible values
		* -1 => Value is not available. 
		*  0 => Value is indeterministic. This happens in a branch aware content when learner is yet to get in to a specific branch.
		*  other values => percentage Slides seen
		*/
		public function get percentageSlidesSeen():Number
		{
			return m_PercentageSlidesSeen;
		}
		/**
		* @private
		*/
		public override function toString():String
		{
			return formatToString("CPSlideExitEvent","type","bubbles","cancelable","eventPhase","captivateVersion","slideNumber","frameNumber","slideLabel","slideProperties","percentageSlidesSeen");
		}
	}
}
