﻿// Copyright 2007. Adobe Systems Incorporated. All Rights Reserved.
package com.adobe.captivate.events 
{
	import flash.events.Event;

	/**
	 * The CPMovieResumeEvent class describes the event object passed to the event listener when a captivate movie is resumed
	 */
	public class CPMovieResumeEvent extends CaptivateEvent 
	{
		/**
		*  The <code>CPMovieResumeEvent.CPMOVIERESUMEEVENT</code> constant defines the value of the
		*  <code>type</code> property of the event object for an <code>CPMovieResumeEvent</code> event.
		*  <p>The properties of the event object have the following values:</p>
		*  <table class="innertable">
		*     <tr><th>Property</th><th>Value</th></tr>
		*     <tr><td><code>bubbles</code></td><td><code>true</code></td></tr>
		*     <tr><td><code>slideNumber</code></td><td>The slide number of the slide in which the movie is resumed</td></tr>
		*     <tr><td><code>frameNumber</code></td><td>The frame number upon which the movie is resumed</td></tr>
		*     <tr><td><code>userPlay</code></td><td><code>true</code> if the resume was due to clicking the play button on the playbar,<code>false</code> otherwise</td></tr>
		*     <tr><td><code>cancelable</code></td><td><code>false</code></td></tr>
		*	  </table>
		*  @eventType CPMovieResumeEvent	
		*/
		public static const CPMOVIERESUMEEVENT:String = "CPMovieResumeEvent";
		/**
		* @private
		*/
		protected var m_FrameNumber:Number;
		/**
		* @private
		*/
		protected var m_SlideNumber:Number;
		/**
		* @private
		*/
		protected var m_UserPlay:Boolean;

		/**
		* @private
		*/
		public function CPMovieResumeEvent(captivateVersion:String="",frameNumber:Number=0,
			slideNumber:Number=0,userPlay:Boolean=false,cancelable:Boolean = false) 
		{
			super(CPMovieResumeEvent.CPMOVIERESUMEEVENT,captivateVersion,cancelable);
			m_FrameNumber = frameNumber;
			m_SlideNumber = slideNumber;
			m_UserPlay = userPlay;
		}
		/**
		* @private
		*/
		public override function clone():Event
		{
			return new CPMovieResumeEvent(captivateVersion,frameNumber,slideNumber,userPlay,cancelable);
		}
		/**
		* The frame number upon which the movie is resumed
		*/
		public function get frameNumber():Number
		{
			return m_FrameNumber;
		}
		/**
		* The slide number of the slide in which the movie is resumed
		*/
		public function get slideNumber():Number
		{
			return m_SlideNumber;
		}
		/**
		* <code>true</code> if the resume was due to clicking the play button on the playbar,<code>false</code> otherwise
		*/
		public function get userPlay():Boolean
		{
			return m_UserPlay;
		}
		/**
		* @private
		*/
		public override function toString():String
		{
			return formatToString("CPMovieResumeEvent","type","bubbles","cancelable","eventPhase","captivateVersion","slideNumber","frameNumber","userPlay");
		}
	}
}
